Double free error on exiting certain applications

##############################################################################
# Try to find RTI Connext DDS
# Once done this will define:
#
#  Connext_FOUND         - system has Connext.
#  Connext_INCLUDE_DIRS  - the Connext include directory.
#  Connext_LIBRARIES     - Link these to use Connext.
#  Connext_ROOT          - Root directory of Connext installation.
#  Connext_IDLGEN_BINARY - Binary for the IDL compiler.
#
# You should set the environment variable $NDDSHOME to your Connext installation
# directory.  Otherwise only a few standard locations are checked.  This script
# also includes the MacroConnext.cmake script, which is useful for generating
# code from your idl.
#
##############################################################################

##############################################################################

# Will set this to false if we cannot find anything.
SET(Connext_FOUND TRUE)

# Get the Connext architecture prefix ("i86" or "x64").
IF (CMAKE_SIZEOF_VOID_P EQUAL 8)
  SET(Connext_ARCH_PREFIX "x64")
ELSE ()
  SET(Connext_ARCH_PREFIX "i86")
ENDIF ()

# Get the CXX compiler version (CMake 2.8.12 and newer provide
# CMAKE_CXX_COMPILER_VERSION, but 2.8.2 on Debian 6 does not).
IF ("${CMAKE_CXX_COMPILER_VERSION}" STREQUAL "")
  EXECUTE_PROCESS(
    COMMAND "${CMAKE_CXX_COMPILER}" "-v"
    ERROR_VARIABLE compiler_output)
  string(REGEX REPLACE "^.*gcc version ([.0-9]*).*$" "\\1" CMAKE_CXX_COMPILER_VERSION ${compiler_output})
ENDIF ()
MESSAGE(STATUS "Compiler version: ${CMAKE_CXX_COMPILER_VERSION}")

# Try to find Connext_ROOT by way of a known include directory.
FIND_PATH(Connext_INCLUDE_DIR
  NAMES
  ndds_version.h
  PATHS
  ${NDDSHOME}/include/ndds
  $ENV{NDDSHOME}/include/ndds
  /opt/rti_connext_dds-5.2.0/include/ndds
  )
IF (NOT "${Connext_INCLUDE_DIR}" STREQUAL "Connext_INCLUDE_DIR-NOTFOUND")
  GET_FILENAME_COMPONENT(Connext_ROOT "${Connext_INCLUDE_DIR}" PATH) # ndds
  GET_FILENAME_COMPONENT(Connext_ROOT "${Connext_ROOT}" PATH)        # include
ELSE ()
  SET(Connext_FOUND FALSE)
ENDIF ()

# Now try to find a valid architecture.
FILE(GLOB Connext_ARCH_DIR_CANDIDATES
  "${Connext_ROOT}/lib/${Connext_ARCH_PREFIX}*/"
  )

# Filter out directories corresponding to newer compilers than the one we're
# using, and order the remaining ones by version number (newest to oldest).
SET(Connext_ARCH_DIRS)
FOREACH (dir ${Connext_ARCH_DIR_CANDIDATES})
  # Extract the compiler version.
  string(REGEX REPLACE "^.*gcc" "" dir_gcc_version ${dir})
  IF (NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${dir_gcc_version})
    LIST(APPEND Connext_ARCH_DIRS ${dir})
  ENDIF ()
ENDFOREACH ()
LIST(SORT Connext_ARCH_DIRS)
LIST(REVERSE Connext_ARCH_DIRS)

MESSAGE(STATUS "Discovered suitable Connext architecture candidates: ${Connext_ARCH_DIRS}")

FIND_PATH(Connext_LIBRARY_PATH
  NAMES
  libnddscorez.a
  PATHS
  ${Connext_ROOT}/lib/${Connext_ARCHITECTURE}
  ${Connext_ARCH_DIRS}
  )

IF (NOT "${Connext_LIBRARY_PATH}" STREQUAL "Connext_LIBRARY_PATH-NOTFOUND")
  GET_FILENAME_COMPONENT(Connext_ARCHITECTURE "${Connext_LIBRARY_PATH}" NAME)
ELSE ()
  SET(Connext_FOUND FALSE)
ENDIF ()

IF (DEFINED Connext_ARCHITECTURE)
  MESSAGE(STATUS "Using RTI Connext architecture '${Connext_ARCHITECTURE}'.")
  MESSAGE(STATUS "Set -DConnext_ARCHITECTURE=... to use a different architecture.")
ENDIF()

# Connext DDS Definitions
SET(Connext_DEFINITIONS "-DRTI -DRTI_UNIX -DRTI_LINUX -DRTI_SHARED_MEMORY")
add_definitions(${Connext_DEFINITIONS})
# Find ndds_c.h header file
FIND_PATH(Connext_INCLUDE_DIRS_NDDS
  NAMES ndds_cpp.h
  PATHS ${Connext_ROOT}/include/ndds
  )

# We need to include both include and include/ndds directories
set(Connext_INCLUDE_DIRS
  ${Connext_ROOT}/include
  ${Connext_ROOT}/include/hpp
  ${Connext_ROOT}/include/hpp/rtiboost
  ${Connext_INCLUDE_DIRS_NDDS}
  ${Connext_INCLUDE_DIRS_NDDS}/hpp
  )

set(nddscore_libname libnddscorez.a)
set(nddsc_libname libnddscz.a)
set(nddscpp_libname libnddscppz.a)
set(nddscpp2_libname libnddscpp2z.a)

find_library(nddscore_lib
  NAMES ${nddscore_libname}
  PATHS ${Connext_LIBRARY_PATH}
  )
find_library(nddsc_lib
  NAMES ${nddsc_libname}
  PATHS ${Connext_LIBRARY_PATH}
  )

find_library(nddscpp_lib
  NAMES ${nddscpp_libname}
  PATHS ${Connext_LIBRARY_PATH}
  )

find_library(nddscpp2_lib
  NAMES ${nddscpp2_libname}
  PATHS ${Connext_LIBRARY_PATH}
  )

set(Connext_LIBRARIES
  ${nddscpp2_lib}
  ${nddscpp_lib}
  ${nddsc_lib}
  ${nddscore_lib}
  ${CMAKE_DL_LIBS}
  ${external_libs}
  )


LIST(APPEND Connext_LIBRARIES "-ldl -lm -lpthread -lrt")

# Binary for the IDL compiler
SET (Connext_IDLGEN_BINARY ${Connext_ROOT}/bin/rtiddsgen)

IF (Connext_FOUND)
  MESSAGE(STATUS "Found Connext DDS libraries: ${Connext_LIBRARIES}")
ELSE (Connext_FOUND)
  IF (Connext_FIND_REQUIRED)
    MESSAGE(FATAL_ERROR "Could not find Connext DDS")
  ENDIF (Connext_FIND_REQUIRED)
ENDIF (Connext_FOUND)


MARK_AS_ADVANCED(Connext_INCLUDE_DIRS Connext_LIBRARIES Connext_IDLGEN_BINARY Connext_DEFINITIONS)